# TITLE OF THE SCRIPT: DYSPHONIA SEVERITY INDEX IN PRAAT (DSI-Praat), v.02.02

# Form for introduction and/or parameterization

form Dysphonia Severity Index in Praat, v.02.02
comment >>>  The original Dysphonia Severity Index (i.e., DSI) is developed
comment by Wuyts et al. (2000). It is a multivariate measure of the degree of
comment of dysphonia and consists of a set of four weighted measures:
comment maximum phonation time, highest fundamental frequency (from the
comment Voice Range Profile of the KayPentax CSL), softest intensity (also from the
comment Voice Range Profile of the KayPentax CSL) and percent jitter (from the
comment Multi-Dimensional Voice Program of the KayPentax CSL).
comment >>> The output and the measures of this script are not equal to but highly
comment resemble the output and the measures of the original DSI: maximum
comment phonation time (i.e., 'mpt'), highest fundamental frequency or f0-high (i.e. 
comment 'fh'), softest intensity of voiced speech or I-low (i.e., 'il') and jitter ppq5 (i.e., 
comment 'ppq'). Their weighted combination is strongly correlated to the original
comment DSI-data.
comment >>> Make sure that the intensity measurements are calibrated. Does the
comment calibration method necessitate the implementation of a calibration factor?
choice choose: 2
button no
button yes:
sentence Calibration_factor 0.9111*self+21
comment >>> For this script it is important to (1) have a recording of phonation(s) as
comment high as possible and name it 'fh', (2) have a recording of phonation(s) as soft
comment as possible and name it 'il', (3) have a recording of at least three medial
comment seconds of a sustained vowel [a:] (i.e., without voice onset and voice offset)
comment and name it 'ppq', and (4) fill in the maximum phonation time here:
positive Maximum_phonation_time_(s) 
comment >>> Additional information (optional):
sentence name_patient
sentence left_dates_(birth_-_assessment) 
sentence right_dates_(birth_-_assessment) 
comment 
comment Script credits: Youri Maryn (14/09/2013)
endform

Erase all
Select inner viewport... 0.5 7.5 0.5 4.5
Axes... 0 1 0 1
Black
Text special... 0.5 centre 0.6 half Helvetica 12 0 Please wait an instant. Depending on the duration and/or the sample rate of the recorded
Text special... 0.5 centre 0.4 half Helvetica 12 0 sound files, this script takes more or less time to process the sounds and calculate the DSI-2.

# --------------------------------------------------------------------------------------------
# PART 1:
# MAXIMUM PHONATION TIME.
# --------------------------------------------------------------------------------------------

mpt = maximum_phonation_time

# --------------------------------------------------------------------------------------------
# PART 2:
# SOFTEST INTENSITY.
# --------------------------------------------------------------------------------------------

select Sound il
To Pitch (cc)... 0 70 15 no 0.03 0.8 0.01 0.35 0.14 600
select Sound il
plus Pitch il
To PointProcess (cc)
select PointProcess il_il
To TextGrid (vuv)... 0.02 0.01
select Sound il
plus TextGrid il_il
Extract intervals where... 1 no "is equal to" V
Concatenate

if choose = 1
To Intensity... 60 0 yes
elsif choose = 2
To Intensity... 60 0 yes
Formula...   'calibration_factor$'
endif

minimumIntensity = Get minimum... 0 0 None

# --------------------------------------------------------------------------------------------
# PART 3:
# HIGHEST FUNDAMENTAL FREQUENCY.
# --------------------------------------------------------------------------------------------

select Sound fh
To Pitch (cc)... 0 70 15 no 0.03 0.8 0.01 0.35 0.14 1300

maximumF0 = Get maximum... 0 0 Hertz None

# --------------------------------------------------------------------------------------------
# PART 4:
# JITTER PPQ5.
# --------------------------------------------------------------------------------------------

select Sound ppq
durationVowel = Get total duration
durationStart=durationVowel-3
if durationVowel>3
Extract part... durationStart durationVowel rectangular 1 no
Rename... ppq2
elsif durationVowel<=3
Copy... ppq2
endif

To Pitch... 0 70 600
select Sound ppq2
plus Pitch ppq2
To PointProcess (cc)
select Sound ppq2
plus Pitch ppq2
plus PointProcess ppq2_ppq2
voiceReport$ = Voice report... 0 0 70 600 1.3 1.6 0.03 0.45
jitterPpq5Pre = extractNumber (voiceReport$, "Jitter (ppq5): ")

jitterPpq5 = jitterPpq5Pre*100

# --------------------------------------------------------------------------------------------
# PART 5:
# CALCULATION OF DSI-2.
# --------------------------------------------------------------------------------------------

dsi2=((9.476+(0.14*mpt)-(0.0329*minimumIntensity)+(0.0045*maximumF0)-(4.53*jitterPpq5))*1.17)-9.96

# --------------------------------------------------------------------------------------------
# PART 6:
# VISUAL OUTPUT.
# --------------------------------------------------------------------------------------------

Erase all
Solid line
Line width... 1
Black
Helvetica
Font size... 1
Select inner viewport... 0.5 7.5 0.1 0.15
Axes... 0 1 0 1
Text... 0 Left 0.5 Half Script: Youri Maryn, PhD
12
Select inner viewport... 0.5 7.5 0 0.5
Axes... 0 1 0 1
Text... 0 Left 0.5 Half ##DYSPHONIA SEVERITY INDEX (DSI) IN PRAAT, v.02.02#
Font size... 8
Select inner viewport... 0.5 7.5 0 0.5
Axes... 0 1 0 3
Text... 1 Right 2.3 Half %%'name_patient$'%
Text... 1 Right 1.5 Half %%°'left_dates$'%
Text... 1 Right 0.7 Half %%'right_dates$'%

Font size... 10
Select inner viewport... 0.5 7.5 0.5 2
Axes... 0 7 4 0
Text... 0.05 Left 0.5 Half Maximum phonation time: ##'mpt:2' s#
Text... 0.05 Left 1.5 Half Softest intensity of voiced speech: ##'minimumIntensity:2' dB#
Text... 0.05 Left 2.5 Half Maximum fundamental frequency: ##'maximumF0:2' Hz#
Text... 0.05 Left 3.5 Half Jitter ppq5: ##'jitterPpq5:2' \% #

Select inner viewport... 0.5 3.8 0.5 2
Draw inner box
Font size... 8
Arrow size... 1
Select inner viewport... 4 7.5 1.25 2
Axes... -10 10 1 0
Paint rectangle... green 1.6 5 0 1
Paint rectangle... red -5 1.6 0 1
Draw arrow... dsi2 1 dsi2 0 
One mark top... -5 yes yes no 
One mark top... -4 yes yes no 
One mark top... -3 yes yes no 
One mark top... -2 yes yes no 
One mark top... -1 yes yes no 
One mark top... 0 yes yes no 
One mark top... 1 yes yes no 
One mark top... 2 yes yes no 
One mark top... 3 yes yes no 
One mark top... 4 yes yes no 
One mark top... 5 yes yes no 
Font size... 16
Select inner viewport... 4 7.5 0.5 1.15
Axes... 0 1 0 1
Text... 0.5 Centre 0.5 Half DSI: ##'dsi2:2'#
Select inner viewport... 4.875 6.625 1.25 2
Draw inner box

# Copy Praat picture

Select inner viewport... 0.5 7.5 0 2
Copy to clipboard

# Removing intermediate objects and selecting original sound object

select all
minus Sound il
minus Sound fh
minus Sound ppq
Remove